mirror of
https://github.com/ARM-software/arm-trusted-firmware.git
synced 2026-07-05 01:18:49 +00:00
Chris Kay
18818426d6
Where previously we cherry-picked individual sources from the libfdt project tree, this change instead integrates the entire project tree into the TF-A repository. Doing so reduces the manual overhead of updating libfdt in the future, as we avoid the need to analyse individual source-level dependencies. libfdt, conveniently, also provides a Makefile designed to ease its integration into foreign build systems (like TF-A's), which we also make use of in this change. Source: https://git.kernel.org/pub/scm/utils/dtc/dtc.git/tree/?h=v1.7.2 Change-Id: I8babcfd27019fdd6d255d550491e1bb733745f27 Signed-off-by: Chris Kay <chris.kay@arm.com>
67 lines
1.4 KiB
Meson
67 lines
1.4 KiB
Meson
version_script = '-Wl,--version-script=@0@'.format(meson.current_source_dir() / 'version.lds')
|
|
if not cc.has_link_argument(version_script)
|
|
version_script = []
|
|
endif
|
|
|
|
sources = files(
|
|
'fdt.c',
|
|
'fdt_addresses.c',
|
|
'fdt_check.c',
|
|
'fdt_empty_tree.c',
|
|
'fdt_overlay.c',
|
|
'fdt_ro.c',
|
|
'fdt_rw.c',
|
|
'fdt_strerror.c',
|
|
'fdt_sw.c',
|
|
'fdt_wip.c',
|
|
)
|
|
|
|
link_args = []
|
|
if cc.has_link_argument('-Wl,--no-undefined')
|
|
link_args += '-Wl,--no-undefined'
|
|
else
|
|
# -undefined error is the equivalent of --no-undefined for the macOS linker,
|
|
# but -undefined would also be understood as a valid argument for GNU ld!
|
|
link_args += cc.get_supported_link_arguments('-Wl,-undefined,error')
|
|
endif
|
|
|
|
link_args += version_script
|
|
libfdt = both_libraries(
|
|
'fdt', sources,
|
|
version: meson.project_version(),
|
|
link_args: link_args,
|
|
link_depends: 'version.lds',
|
|
install: true,
|
|
)
|
|
|
|
if static_build
|
|
link_with = libfdt.get_static_lib()
|
|
else
|
|
link_with = libfdt.get_shared_lib()
|
|
endif
|
|
|
|
libfdt_inc = include_directories('.')
|
|
|
|
libfdt_dep = declare_dependency(
|
|
include_directories: libfdt_inc,
|
|
link_with: link_with,
|
|
)
|
|
|
|
install_headers(
|
|
files(
|
|
'fdt.h',
|
|
'libfdt.h',
|
|
'libfdt_env.h',
|
|
)
|
|
)
|
|
|
|
pkgconfig = import('pkgconfig')
|
|
|
|
pkgconfig.generate(
|
|
libraries: libfdt,
|
|
version: meson.project_version(),
|
|
filebase: 'libfdt',
|
|
name: 'libfdt',
|
|
description: 'Flat Device Tree manipulation',
|
|
)
|