mirror of
https://git.code.sf.net/p/openocd/code
synced 2025-02-16 19:16:01 +00:00
a126229dff
Replace the GPLv2-or-later boilerplate with the SPDX tag. The SPDX tag on files *.c is incorrect, as it should use the C99 single line comment using '//'. But current checkpatch doesn't allow C99 comments, so keep using standard C comments, by now. Change-Id: I380d552940f1c405309a3346454251c0e80b5a45 Signed-off-by: Antonio Borneo <borneo.antonio@gmail.com> Reviewed-on: https://review.openocd.org/c/openocd/+/7159 Tested-by: jenkins
47 lines
1.2 KiB
ArmAsm
47 lines
1.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-or-later */
|
|
|
|
/***************************************************************************
|
|
* Copyright (C) 2010 by Spencer Oliver *
|
|
* spen@spen-soft.co.uk *
|
|
***************************************************************************/
|
|
|
|
.text
|
|
.arm
|
|
.arch armv4t
|
|
|
|
.section .init
|
|
/*
|
|
r0 source address
|
|
r1 address
|
|
r2 FLASH_CR0
|
|
r3 dword count
|
|
r4 result
|
|
r5 busy mask
|
|
*/
|
|
|
|
write:
|
|
mov r4, #0x10000000 /* set DWPG bit */
|
|
str r4, [r2, #0x0] /* FLASH_CR0 */
|
|
str r1, [r2, #0x10] /* FLASH_AR */
|
|
ldr r4, [r0], #4 /* load data */
|
|
str r4, [r2, #0x8] /* FLASH_DR0 */
|
|
ldr r4, [r0], #4 /* load data */
|
|
str r4, [r2, #0xc] /* FLASH_DR1 */
|
|
mov r4, #0x90000000 /* set DWPG and WMS bits */
|
|
str r4, [r2, #0x0] /* FLASH_CR0 */
|
|
busy:
|
|
ldr r4, [r2, #0x0] /* FLASH_CR0 */
|
|
tst r4, r5
|
|
bne busy
|
|
ldr r4, [r2, #0x14] /* FLASH_ER */
|
|
tst r4, #0xff /* do we have errors */
|
|
tsteq r4, #0x100 /* write protection set */
|
|
bne exit
|
|
add r1, r1, #0x8 /* next 8 bytes */
|
|
subs r3, r3, #1 /* decrement dword count */
|
|
bne write
|
|
exit:
|
|
b exit
|
|
|
|
.end
|