ba0621368e
Changes in 4.9.154 net: bridge: Fix ethernet header pointer before check skb forwardable net: Fix usage of pskb_trim_rcsum openvswitch: Avoid OOB read when parsing flow nlattrs vhost: log dirty page correctly net: ipv4: Fix memory leak in network namespace dismantle net_sched: refetch skb protocol for each filter ipfrag: really prevent allocation on netns exit USB: serial: simple: add Motorola Tetra TPG2200 device id USB: serial: pl2303: add new PID to support PL2303TB ASoC: atom: fix a missing check of snd_pcm_lib_malloc_pages ASoC: rt5514-spi: Fix potential NULL pointer dereference ARCv2: lib: memeset: fix doing prefetchw outside of buffer ARC: perf: map generic branches to correct hardware condition s390/early: improve machine detection s390/smp: fix CPU hotplug deadlock with CPU rescan char/mwave: fix potential Spectre v1 vulnerability staging: rtl8188eu: Add device code for D-Link DWA-121 rev B1 tty: Handle problem if line discipline does not have receive_buf uart: Fix crash in uart_write and uart_put_char tty/n_hdlc: fix __might_sleep warning CIFS: Fix possible hang during async MTU reads and writes Input: xpad - add support for SteelSeries Stratus Duo compiler.h: enable builtin overflow checkers and add fallback code Input: uinput - fix undefined behavior in uinput_validate_absinfo() acpi/nfit: Block function zero DSMs acpi/nfit: Fix command-supported detection dm thin: fix passdown_double_checking_shared_status() KVM: x86: Fix single-step debugging x86/selftests/pkeys: Fork() to check for state being preserved x86/kaslr: Fix incorrect i8254 outb() parameters can: dev: __can_get_echo_skb(): fix bogous check for non-existing skb by removing it can: bcm: check timer values before ktime conversion vt: invoke notifier on screen size change perf unwind: Unwind with libdw doesn't take symfs into account perf unwind: Take pgoff into account when reporting elf to libdwfl irqchip/gic-v3-its: Align PCI Multi-MSI allocation on their size s390/smp: Fix calling smp_call_ipl_cpu() from ipl CPU nvmet-rdma: Add unlikely for response allocated check nvmet-rdma: fix null dereference under heavy load f2fs: read page index before freeing btrfs: fix error handling in btrfs_dev_replace_start btrfs: dev-replace: go back to suspended state if target device is missing Linux 4.9.154 Signed-off-by: Greg Kroah-Hartman <gregkh@google.com>
147 lines
2.9 KiB
ArmAsm
147 lines
2.9 KiB
ArmAsm
/*
|
|
* Copyright (C) 2014-15 Synopsys, Inc. (www.synopsys.com)
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/cache.h>
|
|
|
|
/*
|
|
* The memset implementation below is optimized to use prefetchw and prealloc
|
|
* instruction in case of CPU with 64B L1 data cache line (L1_CACHE_SHIFT == 6)
|
|
* If you want to implement optimized memset for other possible L1 data cache
|
|
* line lengths (32B and 128B) you should rewrite code carefully checking
|
|
* we don't call any prefetchw/prealloc instruction for L1 cache lines which
|
|
* don't belongs to memset area.
|
|
*/
|
|
|
|
#if L1_CACHE_SHIFT == 6
|
|
|
|
.macro PREALLOC_INSTR reg, off
|
|
prealloc [\reg, \off]
|
|
.endm
|
|
|
|
.macro PREFETCHW_INSTR reg, off
|
|
prefetchw [\reg, \off]
|
|
.endm
|
|
|
|
#else
|
|
|
|
.macro PREALLOC_INSTR
|
|
.endm
|
|
|
|
.macro PREFETCHW_INSTR
|
|
.endm
|
|
|
|
#endif
|
|
|
|
ENTRY_CFI(memset)
|
|
PREFETCHW_INSTR r0, 0 ; Prefetch the first write location
|
|
mov.f 0, r2
|
|
;;; if size is zero
|
|
jz.d [blink]
|
|
mov r3, r0 ; don't clobber ret val
|
|
|
|
;;; if length < 8
|
|
brls.d.nt r2, 8, .Lsmallchunk
|
|
mov.f lp_count,r2
|
|
|
|
and.f r4, r0, 0x03
|
|
rsub lp_count, r4, 4
|
|
lpnz @.Laligndestination
|
|
;; LOOP BEGIN
|
|
stb.ab r1, [r3,1]
|
|
sub r2, r2, 1
|
|
.Laligndestination:
|
|
|
|
;;; Destination is aligned
|
|
and r1, r1, 0xFF
|
|
asl r4, r1, 8
|
|
or r4, r4, r1
|
|
asl r5, r4, 16
|
|
or r5, r5, r4
|
|
mov r4, r5
|
|
|
|
sub3 lp_count, r2, 8
|
|
cmp r2, 64
|
|
bmsk.hi r2, r2, 5
|
|
mov.ls lp_count, 0
|
|
add3.hi r2, r2, 8
|
|
|
|
;;; Convert len to Dwords, unfold x8
|
|
lsr.f lp_count, lp_count, 6
|
|
|
|
lpnz @.Lset64bytes
|
|
;; LOOP START
|
|
PREALLOC_INSTR r3, 64 ; alloc next line w/o fetching
|
|
|
|
#ifdef CONFIG_ARC_HAS_LL64
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
#else
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
#endif
|
|
.Lset64bytes:
|
|
|
|
lsr.f lp_count, r2, 5 ;Last remaining max 124 bytes
|
|
lpnz .Lset32bytes
|
|
;; LOOP START
|
|
#ifdef CONFIG_ARC_HAS_LL64
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
std.ab r4, [r3, 8]
|
|
#else
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
st.ab r4, [r3, 4]
|
|
#endif
|
|
.Lset32bytes:
|
|
|
|
and.f lp_count, r2, 0x1F ;Last remaining 31 bytes
|
|
.Lsmallchunk:
|
|
lpnz .Lcopy3bytes
|
|
;; LOOP START
|
|
stb.ab r1, [r3, 1]
|
|
.Lcopy3bytes:
|
|
|
|
j [blink]
|
|
|
|
END_CFI(memset)
|
|
|
|
ENTRY_CFI(memzero)
|
|
; adjust bzero args to memset args
|
|
mov r2, r1
|
|
b.d memset ;tail call so need to tinker with blink
|
|
mov r1, 0
|
|
END_CFI(memzero)
|