26400f8207
Changes in 4.9.170 ARC: u-boot args: check that magic number is correct perf/core: Restore mmap record type correctly ext4: add missing brelse() in add_new_gdb_meta_bg() ext4: report real fs size after failed resize ALSA: echoaudio: add a check for ioremap_nocache ALSA: sb8: add a check for request_region IB/mlx4: Fix race condition between catas error reset and aliasguid flows mmc: davinci: remove extraneous __init annotation ALSA: opl3: fix mismatch between snd_opl3_drum_switch definition and declaration thermal/int340x_thermal: Add additional UUIDs thermal/int340x_thermal: fix mode setting tools/power turbostat: return the exit status of a command perf config: Fix an error in the config template documentation perf config: Fix a memory leak in collect_config() perf build-id: Fix memory leak in print_sdt_events() perf top: Fix error handling in cmd_top() perf hist: Add missing map__put() in error case perf evsel: Free evsel->counts in perf_evsel__exit() perf tests: Fix a memory leak of cpu_map object in the openat_syscall_event_on_all_cpus test perf tests: Fix a memory leak in test__perf_evsel__tp_sched_test() irqchip/mbigen: Don't clear eventid when freeing an MSI x86/hpet: Prevent potential NULL pointer dereference x86/cpu/cyrix: Use correct macros for Cyrix calls on Geode processors iommu/vt-d: Check capability before disabling protected memory x86/hw_breakpoints: Make default case in hw_breakpoint_arch_parse() return an error fix incorrect error code mapping for OBJECTID_NOT_FOUND ext4: prohibit fstrim in norecovery mode gpio: pxa: handle corner case of unprobed device rsi: improve kernel thread handling to fix kernel panic 9p: do not trust pdu content for stat item size 9p locks: add mount option for lock retry interval f2fs: fix to do sanity check with current segment number serial: uartps: console_setup() can't be placed to init section HID: i2c-hid: override HID descriptors for certain devices ARM: samsung: Limit SAMSUNG_PM_CHECK config option to non-Exynos platforms ACPI / SBS: Fix GPE storm on recent MacBookPro's cifs: fallback to older infolevels on findfirst queryinfo retry kernel: hung_task.c: disable on suspend crypto: sha256/arm - fix crash bug in Thumb2 build crypto: sha512/arm - fix crash bug in Thumb2 build iommu/dmar: Fix buffer overflow during PCI bus notification soc/tegra: pmc: Drop locking from tegra_powergate_is_powered() lkdtm: Add tests for NULL pointer dereference ARM: 8839/1: kprobe: make patch_lock a raw_spinlock_t appletalk: Fix use-after-free in atalk_proc_exit lib/div64.c: off by one in shift include/linux/swap.h: use offsetof() instead of custom __swapoffset macro tpm/tpm_crb: Avoid unaligned reads in crb_recv() net: stmmac: Set dma ring length before enabling the DMA appletalk: Fix compile regression Linux 4.9.170 Signed-off-by: Greg Kroah-Hartman <gregkh@google.com>
147 lines
3.8 KiB
ArmAsm
147 lines
3.8 KiB
ArmAsm
/*
|
|
* ARC CPU startup Code
|
|
*
|
|
* Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* Vineetg: Dec 2007
|
|
* -Check if we are running on Simulator or on real hardware
|
|
* to skip certain things during boot on simulator
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/entry.h>
|
|
#include <asm/arcregs.h>
|
|
#include <asm/cache.h>
|
|
#include <asm/irqflags.h>
|
|
|
|
.macro CPU_EARLY_SETUP
|
|
|
|
; Setting up Vectror Table (in case exception happens in early boot
|
|
sr @_int_vec_base_lds, [AUX_INTR_VEC_BASE]
|
|
|
|
; Disable I-cache/D-cache if kernel so configured
|
|
lr r5, [ARC_REG_IC_BCR]
|
|
breq r5, 0, 1f ; I$ doesn't exist
|
|
lr r5, [ARC_REG_IC_CTRL]
|
|
#ifdef CONFIG_ARC_HAS_ICACHE
|
|
bclr r5, r5, 0 ; 0 - Enable, 1 is Disable
|
|
#else
|
|
bset r5, r5, 0 ; I$ exists, but is not used
|
|
#endif
|
|
sr r5, [ARC_REG_IC_CTRL]
|
|
|
|
1:
|
|
lr r5, [ARC_REG_DC_BCR]
|
|
breq r5, 0, 1f ; D$ doesn't exist
|
|
lr r5, [ARC_REG_DC_CTRL]
|
|
bclr r5, r5, 6 ; Invalidate (discard w/o wback)
|
|
#ifdef CONFIG_ARC_HAS_DCACHE
|
|
bclr r5, r5, 0 ; Enable (+Inv)
|
|
#else
|
|
bset r5, r5, 0 ; Disable (+Inv)
|
|
#endif
|
|
sr r5, [ARC_REG_DC_CTRL]
|
|
|
|
1:
|
|
|
|
#ifdef CONFIG_ISA_ARCV2
|
|
; Unaligned access is disabled at reset, so re-enable early as
|
|
; gcc 7.3.1 (ARC GNU 2018.03) onwards generates unaligned access
|
|
; by default
|
|
lr r5, [status32]
|
|
bset r5, r5, STATUS_AD_BIT
|
|
kflag r5
|
|
#endif
|
|
.endm
|
|
|
|
.section .init.text, "ax",@progbits
|
|
|
|
;----------------------------------------------------------------
|
|
; Default Reset Handler (jumped into from Reset vector)
|
|
; - Don't clobber r0,r1,r2 as they might have u-boot provided args
|
|
; - Platforms can override this weak version if needed
|
|
;----------------------------------------------------------------
|
|
WEAK(res_service)
|
|
j stext
|
|
END(res_service)
|
|
|
|
;----------------------------------------------------------------
|
|
; Kernel Entry point
|
|
;----------------------------------------------------------------
|
|
ENTRY(stext)
|
|
|
|
CPU_EARLY_SETUP
|
|
|
|
#ifdef CONFIG_SMP
|
|
GET_CPU_ID r5
|
|
cmp r5, 0
|
|
mov.nz r0, r5
|
|
bz .Lmaster_proceed
|
|
|
|
; Non-Masters wait for Master to boot enough and bring them up
|
|
; when they resume, tail-call to entry point
|
|
mov blink, @first_lines_of_secondary
|
|
j arc_platform_smp_wait_to_boot
|
|
|
|
.Lmaster_proceed:
|
|
#endif
|
|
|
|
; Clear BSS before updating any globals
|
|
; XXX: use ZOL here
|
|
mov r5, __bss_start
|
|
sub r6, __bss_stop, r5
|
|
lsr.f lp_count, r6, 2
|
|
lpnz 1f
|
|
st.ab 0, [r5, 4]
|
|
1:
|
|
|
|
#ifdef CONFIG_ARC_UBOOT_SUPPORT
|
|
; Uboot - kernel ABI
|
|
; r0 = [0] No uboot interaction, [1] cmdline in r2, [2] DTB in r2
|
|
; r1 = magic number (always zero as of now)
|
|
; r2 = pointer to uboot provided cmdline or external DTB in mem
|
|
; These are handled later in handle_uboot_args()
|
|
st r0, [@uboot_tag]
|
|
st r1, [@uboot_magic]
|
|
st r2, [@uboot_arg]
|
|
#endif
|
|
|
|
; setup "current" tsk and optionally cache it in dedicated r25
|
|
mov r9, @init_task
|
|
SET_CURR_TASK_ON_CPU r9, r0 ; r9 = tsk, r0 = scratch
|
|
|
|
; setup stack (fp, sp)
|
|
mov fp, 0
|
|
|
|
; tsk->thread_info is really a PAGE, whose bottom hoists stack
|
|
GET_TSK_STACK_BASE r9, sp ; r9 = tsk, sp = stack base(output)
|
|
|
|
j start_kernel ; "C" entry point
|
|
END(stext)
|
|
|
|
#ifdef CONFIG_SMP
|
|
;----------------------------------------------------------------
|
|
; First lines of code run by secondary before jumping to 'C'
|
|
;----------------------------------------------------------------
|
|
.section .text, "ax",@progbits
|
|
ENTRY(first_lines_of_secondary)
|
|
|
|
; setup per-cpu idle task as "current" on this CPU
|
|
ld r0, [@secondary_idle_tsk]
|
|
SET_CURR_TASK_ON_CPU r0, r1
|
|
|
|
; setup stack (fp, sp)
|
|
mov fp, 0
|
|
|
|
; set it's stack base to tsk->thread_info bottom
|
|
GET_TSK_STACK_BASE r0, sp
|
|
|
|
j start_kernel_secondary
|
|
END(first_lines_of_secondary)
|
|
#endif
|